apply plugin: 'java'
apply plugin: 'com.google.protobuf'
apply plugin: 'maven'

version = '0.15-SNAPSHOT'
archivesBaseName = 'bitcoinj-core'

dependencies {
    compile 'org.bouncycastle:bcprov-jdk15on:1.60'
    implementation 'com.lambdaworks:scrypt:1.4.0'
    implementation 'com.google.guava:guava:25.1-android'
    compile 'com.google.protobuf:protobuf-java:3.5.1'
    implementation 'com.squareup.okhttp3:okhttp:3.12.0'
    implementation 'org.slf4j:slf4j-api:1.7.25'
    implementation 'net.jcip:jcip-annotations:1.0'
    compileOnly 'org.fusesource.leveldbjni:leveldbjni-all:1.8'
    testImplementation 'junit:junit:4.12'
    testImplementation 'org.easymock:easymock:3.2'
    testImplementation 'com.fasterxml.jackson.core:jackson-databind:2.5.2'
    testImplementation 'org.slf4j:slf4j-jdk14:1.7.25'
    testImplementation 'com.h2database:h2:1.3.167'
    testImplementation 'org.fusesource.leveldbjni:leveldbjni-all:1.8'
}

sourceCompatibility = 1.7
compileJava.options.encoding = 'UTF-8'
compileTestJava.options.encoding = 'UTF-8'

protobuf {
    generatedFilesBaseDir = new File(projectDir, '/src') // workaround for '$projectDir/src'
}

test {
    exclude 'org/bitcoinj/net/NetworkAbstractionTests*'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives sourcesJar
    archives javadocJar
}